Nand2Tetris Chapter 2

Nand2Tetris :  https://www.coursera.org/learn/build-a-computer

Build a Modern Computer from First Principles: From Nand to Tetris (Project-Centered Course)

---

Chapter 2

Boolean Arithmetic and the ALU

만들어야 하는 Boolean Arithmetic

Chapter 2에서는 Chapter 1에서의 연산자들을 이용해 ALU를 제작해야 한다.

---

1. HalfAdder

// This file is part of www.nand2tetris.org
// and the book "The Elements of Computing Systems"
// by Nisan and Schocken, MIT Press.
// File name: projects/02/HalfAdder.hdl

/**
 * Computes the sum of two bits.
 */

CHIP HalfAdder {
    IN a, b;    // 1-bit inputs
    OUT sum,    // Right bit of a + b 
        carry;  // Left bit of a + b

    PARTS:
	Xor (a=a, b=b, out=sum);
    And (a=a, b=b, out=carry);
}

 

2. FullAdder

// This file is part of www.nand2tetris.org
// and the book "The Elements of Computing Systems"
// by Nisan and Schocken, MIT Press.
// File name: projects/02/FullAdder.hdl

/**
 * Computes the sum of three bits.
 */

CHIP FullAdder {
    IN a, b, c;  // 1-bit inputs
    OUT sum,     // Right bit of a + b + c
        carry;   // Left bit of a + b + c

    PARTS:
    HalfAdder (a=a, b=b, sum=aSumb, carry=carry1);
	HalfAdder (a=aSumb, b=c, sum=sum, carry=carry2);
	Or (a=carry1, b=carry2, out=carry);
	
}

 

3. Add16

// This file is part of www.nand2tetris.org
// and the book "The Elements of Computing Systems"
// by Nisan and Schocken, MIT Press.
// File name: projects/02/Adder16.hdl

/**
 * Adds two 16-bit values.
 * The most significant carry bit is ignored.
 */

CHIP Add16 {
    IN a[16], b[16];
    OUT out[16];

    PARTS:
	HalfAdder (a=a[0], b=b[0], sum=out[0], carry=carry1);
	FullAdder (a=a[1], b=b[1], c=carry1, sum=out[1], carry=carry2);
	FullAdder (a=a[2], b=b[2], c=carry2, sum=out[2], carry=carry3);
	FullAdder (a=a[3], b=b[3], c=carry3, sum=out[3], carry=carry4);
	FullAdder (a=a[4], b=b[4], c=carry4, sum=out[4], carry=carry5);
	FullAdder (a=a[5], b=b[5], c=carry5, sum=out[5], carry=carry6);
	FullAdder (a=a[6], b=b[6], c=carry6, sum=out[6], carry=carry7);
	FullAdder (a=a[7], b=b[7], c=carry7, sum=out[7], carry=carry8);
	FullAdder (a=a[8], b=b[8], c=carry8, sum=out[8], carry=carry9);
	FullAdder (a=a[9], b=b[9], c=carry9, sum=out[9], carry=carry10);
	FullAdder (a=a[10], b=b[10], c=carry10, sum=out[10], carry=carry11);
	FullAdder (a=a[11], b=b[11], c=carry11, sum=out[11], carry=carry12);
	FullAdder (a=a[12], b=b[12], c=carry12, sum=out[12], carry=carry13);
	FullAdder (a=a[13], b=b[13], c=carry13, sum=out[13], carry=carry14);
	FullAdder (a=a[14], b=b[14], c=carry14, sum=out[14], carry=carry15);
	FullAdder (a=a[15], b=b[15], c=carry15, sum=out[15], carry=carry);
}

 

4. Inc16

// This file is part of www.nand2tetris.org
// and the book "The Elements of Computing Systems"
// by Nisan and Schocken, MIT Press.
// File name: projects/02/Inc16.hdl

/**
 * 16-bit incrementer:
 * out = in + 1 (arithmetic addition)
 */

CHIP Inc16 {
    IN in[16];
    OUT out[16];

    PARTS:
	Xor (a=in[0], b=in[0], out=zero);
	Not (in=zero, out=one);
	Add16 (a=in, b[0]=one, out=out);
}

 

5. ALU

// This file is part of www.nand2tetris.org
// and the book "The Elements of Computing Systems"
// by Nisan and Schocken, MIT Press.
// File name: projects/02/ALU.hdl

/**
 * The ALU (Arithmetic Logic Unit).
 * Computes one of the following functions:
 * x+y, x-y, y-x, 0, 1, -1, x, y, -x, -y, !x, !y,
 * x+1, y+1, x-1, y-1, x&y, x|y on two 16-bit inputs, 
 * according to 6 input bits denoted zx,nx,zy,ny,f,no.
 * In addition, the ALU computes two 1-bit outputs:
 * if the ALU output == 0, zr is set to 1; otherwise zr is set to 0;
 * if the ALU output < 0, ng is set to 1; otherwise ng is set to 0.
 */

// Implementation: the ALU logic manipulates the x and y inputs
// and operates on the resulting values, as follows:
// if (zx == 1) set x = 0        // 16-bit constant
// if (nx == 1) set x = !x       // bitwise not
// if (zy == 1) set y = 0        // 16-bit constant
// if (ny == 1) set y = !y       // bitwise not
// if (f == 1)  set out = x + y  // integer 2's complement addition
// if (f == 0)  set out = x & y  // bitwise and
// if (no == 1) set out = !out   // bitwise not
// if (out == 0) set zr = 1
// if (out < 0) set ng = 1

CHIP ALU {
    IN  
        x[16], y[16],  // 16-bit inputs        
        zx, // zero the x input?
        nx, // negate the x input?
        zy, // zero the y input?
        ny, // negate the y input?
        f,  // compute out = x + y (if 1) or x & y (if 0)
        no; // negate the out output?

    OUT 
        out[16], // 16-bit output
        zr, // 1 if (out == 0), 0 otherwise
        ng; // 1 if (out < 0),  0 otherwise

    PARTS:
	// zx and nx 
	Mux16 (a=x, b=false, sel=zx, out=zxx);
	Not16 (in=zxx, out=Notzxx);
	Mux16 (a=zxx, b=Notzxx, sel=nx, out=nxx);
	
	// zy and ny
	Mux16 (a=y, b=false, sel=zy, out=zyy);
	Not16 (in=zyy, out=Notzyy);
	Mux16 (a=zyy, b=Notzyy, sel=ny, out=nyy);
	
	//f
	Add16 (a=nxx, b=nyy, out=Addxy);
	And16 (a=nxx, b=nyy, out=Andxy);
	Mux16 (a=Andxy, b=Addxy, sel=f, out=beforeno);
	
	//no
	Not16 (in=beforeno, out=Notbeforeno);
	Mux16 (a=beforeno, b=Notbeforeno, sel=no, out=out, out[0..7]=lowout, out[8..15]=highout, out[15]=ng);
	
	//zr
	Or8Way (in=lowout, out=zr1);
	Or8Way (in=highout, out=zr2);
	Or (a=zr1, b=zr2, out=Notzr);
	Not (in=Notzr, out=zr);
}